Rat

Overdrive et distorsion · Circuit · Étain

Un ampli op poussé fort dans des diodes au silicium, avec un filtre qui retire des aigus à mesure qu’on le tourne.

Une pédale, trois caractères, tous sur le bouton Distortion. En bas, c’est une overdrive granuleuse qui pousse l’ampli ; à midi, une distorsion épaisse et mordante qui se pose au milieu du groupe ; tout en haut, elle frôle la fuzz. Le deuxième bouton retire des aigus à mesure que tu le tournes : en bas pour un tranchant qui mord, en haut pour un mur sombre et laineux. Groupes grunge, stars du rock et guitaristes de jazz l’ont tous eue à leurs pieds.

Son histoire

La RAT vient de Kalamazoo, dans le Michigan, et tient son nom du sous-sol infesté de rongeurs du bâtiment de ProCo où elle a été conçue. Au milieu des années 70, Scott Burnham, ingénieur chez ProCo, y travaille avec l’aide de Steve Kiraly. On raconte qu’il a monté une résistance de 47 Ω là où il voulait 470 Ω : le gain grimpe très haut, et avec les diodes d’écrêtage la distorsion devient bien plus agressive. Une poignée d’exemplaires sont fabriqués sur commande à la fin des années 70, et elle entre au catalogue de ProCo en 1979.

En 1981, son réglage de tonalité est inversé, plus sombre en tournant vers la droite, et son nom passe de Tone à Filter. La RAT2 remplace l’originale en 1988, avec un témoin lumineux ; en 1996 au plus tard, son ampli op LM308, déclaré obsolète par Texas Instruments, a été remplacé. D’autres versions suivent : la TurboRAT, avec des LED rouges à la place des diodes, la You Dirty RAT, avec des diodes au germanium, des rééditions des premiers boîtiers. Guitar World lui attribue d’avoir posé le modèle de ce qu’est le son d’une distorsion.

Kurt Cobain, David Gilmour, Dave Grohl, Jeff Beck, Thom Yorke, Vernon Reid, Joe Perry et Andy Summers en ont joué une, et des jazzmen aussi, comme John Scofield et Bill Frisell.

La variante que tu joues

C’est le schéma LiveSPICE de la Pro Co Rat, converti composant par composant pour robine-spice (LiveSPICE est sous licence MIT, © Dillon Sharlet). L’année de RAT que ses auteurs ont relevée n’est pas dite. On y trouve les composants qui signent le circuit : un ampli op LM308, deux diodes silicium 1N914 vers la masse après lui, un JFET 2N5458 en buffer de sortie, et dans la branche de gain de l’ampli op le fameux 47 Ω (R3) à côté d’un 560 Ω, qui permettent au potentiomètre de Distortion de monter le gain très haut. Le filtre est une résistance de 1,5 kΩ, le potentiomètre de 100 kΩ et 3,3 nF : bouton tout en haut, sa fréquence de coupure est d’environ 475 Hz, les « environ 500 Hz » pour lesquels la RAT est connue.

Trois boutons : Distortion, Tone (le Filter de la RAT2 : il retire des aigus à mesure qu’on le monte) et Volume. Dans la bibliothèque, elle s’appelle Rat, avec les overdrives.

Ce qui n’est pas la pédale :

• l’alimentation : un 9 V idéal, et un 4,5 V idéal pour la polarisation ;
• l’ampli op, un macro-modèle aux chiffres d’un LM308 (300 V/mV, 1 MHz) : un pôle et les rails comme butées. Le vrai LM308 est lent, et sa vitesse de balayage limitée est ce qui l’empêche d’amplifier autant les fréquences les plus hautes ; le macro-modèle n’a pas cette limite ;
• les diodes et le JFET : les modèles LiveSPICE d’une 1N914 et d’un 2N5458 ;
• le footswitch : il n’y a pas de chemin de bypass, l’effet est toujours actif.

Pour commencer

• Distortion bas, Tone bas, Volume haut : une overdrive qui garde son tranchant, pour pousser un ampli qui sature déjà un peu.
• Distortion et Tone vers midi : une distorsion épaisse, au milieu du groupe.
• Distortion à fond, Tone haut : sombre et saturée, vers la fuzz.

Le circuit

Une ligne par composant : son nom, les nœuds où il est branché, sa valeur (1e3 vaut 1 kΩ, 3.3e-9 vaut 3,3 nF). Une ligne P est un potentiomètre (ses deux extrémités puis le curseur entre les deux) ; curseur relié à l’une de ses extrémités, c’est une résistance variable. X1 est l’ampli op et JQ1 le JFET, décrits à la fin ; D1 et D2 sont les deux diodes.

Pro Co Rat
* Converted by `spice-lab convert` from the LiveSPICE schematic
* "Pro Co Rat.schx" (LiveSPICE is MIT licensed, (c) Dillon Sharlet).
V1 in 0 DC 0
C4 n1 n2 4.7e-5
R5 n3 n1 1e3
C1 n2 n4 1e-10
C2 n5 0 4.7e-6
C3 n6 0 2.2e-6
R2 n4 n5 5.6e2
R3 n4 n6 4.7e1
R6 n7 n8 1.5e3
C5 n8 0 3.3e-9
D1 0 n3 d_1n914
D2 n3 0 d_1n914
C6 n9 n8 2.2e-8
R1 n9 0 1e6
X1 n11 n4 n2 n10 0 opamp_lm308
V3 n10 0 DC 9e0
R7 in 0 1e6
C8 n12 in 2.2e-8
R8 n12 n13 1e6
R9 n11 n12 1e3
C9 n11 0 1e-9
V4 n13 0 DC 4.5e0
JQ1 n14 n9 n15 j_2n5458
R4 n15 0 1e4
V2 n14 0 DC 9e0
C7 n16 n15 1e-6
PDistortion n2 n2 n4 1e5 taper=log pos=0.5
PTone n7 n7 n3 1e5 taper=log pos=0.5
PVolume n16 out 0 1e5 taper=log pos=0.5
.subckt opamp_lm308 inp inn out vcc vee
Rin inp inn 4e7
Ggain 0 stage inp inn 3e2
Rstage stage 0 1e3
Cstage stage 0 4.774648292756861e-5
Vhigh vcc top DC 2
Dhigh stage top opamp_clamp
Vlow bottom vee DC 2
Dlow bottom stage opamp_clamp
Gout 0 out stage out 2e-2
.ends
.model d_1n914 D(IS=2.52e-9 N=1.752e0)
.model j_2n5458 NJF(VTO=-2.882e0 BETA=4.889e-4 LAMBDA=3.167e-3 IS=1e-14)
.model opamp_clamp D(IS=8e-16 N=1)
.input V1
.output out

Mesurée face à

Huit captures d’une ProCo RAT 2 faites par gloo (TONE3000 #102945), la pédale d’un ami, chacune nommée d’après les positions de ses trois boutons (Distortion, Filter, Volume). Un bouton à « 3 » sur 10 est une rotation de 0,3, quelle que soit sa loi. Ces captures ne sont pas à nous : on les nomme, on ne les partage pas.

Les captures ne disent pas à quel niveau elles ont été jouées. Un niveau a été ajusté une fois, sur la capture 5/5/7 (0,04 V pour un signal à pleine échelle), et gardé pour les huit.

Sa note

Étain, score 30,4. Ses trois boutons sont d’accord avec ngspice, mais le calcul lui-même n’en est pas aussi proche qu’il le devrait : −29,3 dB à 48 kHz, là où l’échelle demande −60 dB pour la note pleine, et −55,8 dB à 192 kHz. Et sur une prise de guitare, aucun réglage n’est proche de la RAT 2 capturée :

À chaque réglage, l’écart est à peu près aussi fort que le signal lui-même, et presque toutes ses trames sont au-dessus du seuil de masquage de l’oreille. Un réglage compte comme proche à partir de −10 dB et d’un PEAQ de −2 : aucun n’en approche.

Cette page ne dit donc pas que le modèle sonne comme une RAT : c’est le circuit de la RAT tel que LiveSPICE l’a dessiné, et la mesure dit qu’il reste loin de la seule pédale à laquelle il a été comparé. Pourquoi n’a pas encore été trouvé. Trois choses diffèrent, on le sait, et aucune n’a été écartée : le niveau d’entrée, que les captures ne donnent pas et qui a été ajusté ; la vitesse de balayage du LM308, absente du macro-modèle ; et l’ampli op de la pédale capturée, qui dans une RAT2 peut être un LM308 ou ce qui l’a remplacé.

Sources : Pro Co RAT (Wikipédia), LiveSPICE, captures de la ProCo Rat 2 par gloo (TONE3000).